Zigqurat

MPU-6050 è un processore di movimento : giroscopio su 3 assi e accellerometro sempre su 3 assi + sensore di temperatura.

Non staremo qui a descrivere in dettaglio le caratteristiche del’integrato dato che c’è un ampia letteratura sulla rete, ci limiteremo all’essenziale per programmare con gambas3.

Inanzitutto è conosciuto come modulo completo con la sigla GY-521, che sul raspberry pi può essere collegato direttamente sui gpio nel modo seguente:

A parte i 2 collegamenti di alimentazione, rosso +3.3v e nero ground, il giallo e il verde si collegano alle porte che gestiscono il protocollo di comunicazione I2C, che deve essere abilitato a livello kernel.

Per abilitare il canale I2C, è possibile in modalità gui dal menù applicazioni->Configurazione di Raspberry Pi nella scheda Interfacce e abilitare premendo lo switch in corrispondenza di I2C, mentre da cli avviare il comando <sudo raspi-config>, selezionare Interface options e abilitare la scelta I2C.

In entrami i casi riavviare il sistema.

Prima di entrare nel merito del codice in Gambas fare riferimento ai requisiti minimi del sistema ed alle librerie necessarie all’esecuzione dell’applicativo:

Il progetto sarà <Comand-line application> con l’aggiunta del componente <ncurses>.

I moduli da importare nel progetto sono i seguenti:

Infine il modulo principale Main:

' Gambas module file

Public hWin As Window
'Public hScreen As Screen
Public hObserver As Observer

Public WinH As Integer 
Public WinW As Integer  
Public ScrH As Integer
Public ScrW As Integer
Public bLowSize As Integer

Public iDivClock As Byte
Public fd As Integer

Public VisualTime As Float = 0.02

Public Sub Main()

Dim Acc_x, Acc_y, Acc_z As Float
Dim Gyro_x, Gyro_y, Gyro_z As Float
Dim Temper As Float
Dim Ax, Ay, Az As Float
Dim Gx, Gy, Gz As Float
Dim i As Integer
Dim ChiSono As Byte

hWin = New Window(True, 0, 0, 78, 24) As "WinEvent"
hObserver = New Observer(Screen) As "EvRes"

WinH = 24
WinW = 78
ScrH = 26
ScrW = 80


MGpio.wiringPiSetup()
fd = MGpio.wiringPiI2CSetup(Mpu6050.Device_Address)
Mpu6050.Setup(fd)
ChiSono = Mpu6050.ReadReg8(fd, Mpu6050.WHO_AM_I) 
Mpu6050.WriteOffSetDir(fd)
iDivClock = Mpu6050.ReadReg8(fd, Mpu6050.SMPLRT_DIV)


hWin.SetFocus()
Screen.Cursor = Cursor.Hidden



Do
  If bLowSize Then
    
    hWin.PrintCenter("Ripristinare il terminale")
    
  Else
    
    hWin.Print(" Adress " & Hex(ChiSono) & "  clock=8Khz/" & (MGpio.wiringPiI2CReadReg8(fd, Mpu6050.SMPLRT_DIV) + 1) & " visual=" & VisualTime & "s  <P>=wait 10s <q>=exit", 0, 0)
    hWin.Print(" accx      accy      accz      gyrx      gyry      gyrz     temper", 0, 1)

    For i = 2 To 22
    
      Acc_x = Mpu6050.ReadReg16(fd, Mpu6050.ACCEL_XOUT_H) / Mpu6050.RESACC
      Acc_y = Mpu6050.ReadReg16(fd, Mpu6050.ACCEL_YOUT_H) / Mpu6050.RESACC
      Acc_z = Mpu6050.ReadReg16(fd, Mpu6050.ACCEL_ZOUT_H) / Mpu6050.RESACC
      Gyro_x = Mpu6050.ReadReg16(fd, Mpu6050.GYRO_XOUT_H) / Mpu6050.RESGYR
      Gyro_y = Mpu6050.ReadReg16(fd, Mpu6050.GYRO_YOUT_H) / Mpu6050.RESGYR
      Gyro_z = Mpu6050.ReadReg16(fd, Mpu6050.GYRO_ZOUT_H) / Mpu6050.RESGYR
      Temper = Mpu6050.ReadReg16(fd, Mpu6050.TEMPER_OUT_H) / 340 + 36.53
    
      hWin.Print(Format(Acc_x, "0.###"), 1, i)
      hWin.Print(Format(Acc_y, "0.###"), 10, i)
      hWin.Print(Format(Acc_z, "0.###"), 20, i)
      hWin.Print(Format(Gyro_x, "0.###"), 30, i)
      hWin.Print(Format(Gyro_y, "0.###"), 40, i)
      hWin.Print(Format(Gyro_z, "0.###"), 50, i)
      hWin.Print(Format(Temper, "0.###"), 60, i)
    
    
    Next
  
  Endif
  
  Wait VisualTime
  hWin.SetFocus()

Loop
  
End

Public Sub WinEvent_Read()

Dim iKey As Integer = Window.Read()

  If iKey = Key["p"] Then
 
    Wait 10
    
  Endif
  
  If iKey = Key["q"] Then
    Quit
  Endif
  
  If iKey = Key.Up Then
    Inc iDivClock
    MGpio.wiringPiI2CWriteReg8(fd, Mpu6050.SMPLRT_DIV, iDivClock)
  Endif
  If iKey = Key.Down Then
    Dec iDivClock
    MGpio.wiringPiI2CWriteReg8(fd, Mpu6050.SMPLRT_DIV, iDivClock)
  Endif
  
  If iKey = Key.PageUp Then
    VisualTime += 0.02
  Endif
  If iKey = Key.PageDown Then
    VisualTime -= 0.02
  Endif
  
  hWin.Raise()
End



Public Sub EvRes_Resize()
  
  Screen.Beep
  If Screen.H < 26 Or Screen.W < 70 Then
    bLowSize = True
    hWin.Clear()
  Else If bLowSize
    bLowSize = False
    hWin.Clear()
  Endif
  
End

L’applicativo mostrera i valori letti presentati dal MPU con il rateo selezionato :

premendo <p> per 10 secondi non verrà aggiornata la schermata

<q> si esce dal programma

Le frecce <up> e <down> aumentano o diminuiscono il divisore di frequenza.

<pageUp> e <pageDown> incrementano o diminuiscono il tempo di visualizzazione.

Il raspberry pi non mette a disposizione porte analogiche, ma è possibile aggirare la limitazione con vari espedienti (procurarsi un convertitore A/D ad esempio).

Oppure utilizare un condensatore adeguato e con un sempllice circuito è possibile programmare un sensore analogico sulla base della sua resistenza.

Il fotoresitore o LDR è un buon esempio.

La formula che ci permette di avere dei valori coerenti e la seguente:

t = R * C

t è il tempo impiegato per caricare il condensatore al 63%
R la resistenza in Ohm
C il condensatore in F(arad)

L’ esempio di un Resistenza di 10Kohm e un Condensatore di 10uF darà:

t = 10000hom * 0.00001F = 0.1 secondi (100 millisecondi)

Questa è la teoria ma dato che il nostro approccio è da programmatori non ci dilungheremo su alcuni fattori da considerare per avere dei valori precisi, ad esempio il fatto che il raspberry considere il valore basso con una tensione sotto 1.8v circa, sulla resistenza dello stesso circuito, che non siamo in realtime… etc.

La visualizzazione del progetto:

Componenti:

1 Condensatore da 10uF

1 LDR o fotoresistore

Il sorgente in gambas3 tipologia Command-line application :

' Gambas module file

' RC


Public iCount As Integer
Public iaVal[220] As Integer
Public iMedia As Integer
Public DiffTime As Float

Public Const NSAM As Integer = 32     'Numero di misurazioni
Public Const iPin As Integer = 1      'Porta wiringpi 
Public Const CAP As Float = 0.00001   'Condensatore utilizzato 10uf
Public Const CA As Float = 2.130620985    'Fattore di aggiustamento

Public Sub Main()
  Dim StartTime As Float
  Dim rc, res As Float
  Dim iIndex As Integer
  
  Print "Test RC - resistenza * condensatore"
  
  If MGpio.wiringPiSetup() = -1 Then
    Print "errrore = wiringPi non inizializzato" 
    Quit -1
  Endif

  Do
    
    DiffTime = 0.0
    
    For iIndex = 0 To NSAM - 1
      
      iCount = 0
      MGpio.pinMode(iPin, MGpio.PIN_OUTPUT)
      MGpio.digitalWrite(iPin, MGpio.PIN_LOW)
      
      Wait 0.005
      MGpio.pinMode(iPin, MGpio.PIN_INPUT)
      
      StartTime = Timer
      While MGpio.digitalRead(iPin) = MGpio.PIN_LOW
        Inc iCount
      Wend
      DiffTime += Timer - StartTime
      
      iaVal[iIndex] = iCount
      
    Next
    
    iMedia = 0
    For iIndex = 0 To NSAM - 1
      iMedia += iaVal[iIndex]
    Next
        
    Rep()
    
  Loop
  
End

Public Sub Rep()
  
  Dim rc, res As Float
  
    Print "---------------"

    Print Format(iMedia / NSAM, "0#  Contatore")
    
    'calcolo rc (resistenza * condensatore)
    rc = DiffTime / NSAM * CA           'Timer
    Print Format(rc, "0.###### Secondi")
    
    'calcolo resistenza
    res = rc / CAP
    Print Format(res, "0# Ohm")
    
    Print Time(Now); "  Tempo"
  
End

Il progetto comprende il modulo MGpio e deve essere installata la libreria wiringPi.

La configurazione usata e l’installazione della libreria la potete trovare qui:

' Gambas module file
'' MGpio

Library "/usr/lib/libwiringPi"
''Definisce la libreria e la sua posizione nel file system

Public Extern wiringPiSetup() As Integer
'Inizializza la libreria

Public Extern pinMode(pin As Integer, pud As Integer)
'Configura la modalità operativa della porta

Public Extern digitalWrite(pin As Integer, value As Integer)
'Attiva o disattiva il segnale di uscita della porta

Public Extern digitalRead(pin As Integer) As Integer        
 'Legge lo stato della porta (low=0, high=1)

Public Const PIN_IN As Integer = 0
Public Const PIN_OUT As Integer = 1
'Modalità operativa porte

Public Const PIN_LOW As Integer = 0
Public Const PIN_HIGH As Integer = 1
'Stato delle porte

Il programma è composto da un loop infinito (Do Loop) che contiene un altro ciclo (For Next) che memorizza un numero di misurazioni (NSAM) da cui si deriva una media , invece il ciclo While sonda se è presente una tensione che se è alta è in fase di carica del condensatore ed esce quando diventa bassa e memorizza un contatore e il tempo di carica .

Ricordo che la resistenza del LDR diminuisce con l’aumento dell’intensita della luce e viceversa, più luce più velocemente carica il condensatore.

Il report mostra:

1 – la media del contatore

2 – il tempo impiegato (media)

3 – l’approssimazione del calcolo della resistenza

4 – l’ora della rilevazione